@echo off
echo ============================================================
echo  MonitorOsservatorio - Diagnostica
echo ============================================================
echo.

set "APPDIR=%~dp0"
if "%APPDIR:~-1%"=="\" set "APPDIR=%APPDIR:~0,-1%"
set "PYTHONPATH=%APPDIR%"

echo APPDIR : %APPDIR%
echo USERNAME: %USERNAME%
echo.

echo [1] Verifica Python embedded...
IF EXIST "%APPDIR%\python\python.exe" (
    echo     OK - python.exe trovato
) ELSE (
    echo     ERRORE - python.exe NON trovato
    goto fine
)

echo [2] Verifica versione Python...
"%APPDIR%\python\python.exe" --version
echo.

echo [3] Verifica moduli necessari...
"%APPDIR%\python\python.exe" -c "import flask; print('    flask:', flask.__version__)"
"%APPDIR%\python\python.exe" -c "import webview; print('    pywebview:', webview.__version__)"
"%APPDIR%\python\python.exe" -c "import openpyxl; print('    openpyxl:', openpyxl.__version__)"
"%APPDIR%\python\python.exe" -c "import loguru; print('    loguru: OK')"
"%APPDIR%\python\python.exe" -c "import pyodbc; print('    pyodbc: OK')"
echo.

echo [4] Verifica modulo app...
"%APPDIR%\python\python.exe" -c "import app; print('    app: OK')"
echo.

echo [5] Avvio applicazione (con console)...
echo     Chiudi la finestra dell applicazione per tornare qui.
echo.
set "MONITOR_SERVER_DIR=\\Mediaset.it\cologno\Osservatorio_Progetti\MonitorOsservatorio"
"%APPDIR%\python\python.exe" -m app.main
echo.

:fine
echo ============================================================
pause